Windows 10 cum descoperi licența fără programe adiționale

Windows 10 cum descoperi licența fără programe adiționale

Windows 10 este un sistem de operare foarte complex,mi s-a întâmplat de multe ori să nu mai pot vizualiza licența preinstalată cu care a venit pc-ul d

Cum descoperiti si descarcati driverii necunoscuti din Windows
Cum activați funcția SlideToShutdown din Windows 10
Cum optimizati Windows 10 cu cea mai noua versiune gratuita CCleaner

Windows 10 este un sistem de operare foarte complex,mi s-a întâmplat de multe ori să nu mai pot vizualiza licența preinstalată cu care a venit pc-ul deoarece s-a șters din eticheta lipită pe spate,în anumite cazuri nici nu ai posibilitatea să vezi licență la pc deși ai cumpărat pc-ul cu licența,mai nou în cazul licențelor preinstalate nu îți mai dă un dvd sau o informație vizuală despre licența respectivă,pur si simplu este instalată în windows 10 si se activează odată ce intri pe internet.

Chiar dacă aveți posibilitatea să actualizați Windows 10 gratuit acum dacă sunteți utilizator de Windows și puteți actualiza cu succes Windows 7 sau Windows 8 în Windows 10, cheia de produs Windows 10 pare să nu fie importantă pentru dvs. deoarece nu aveți nevoie pentru a activa Windows 10 manual. Cu toate acestea, dacă primiți un nou computer preinstalat cu Windows 10 și acum doriți să îl reinstalați pentru a rezolva unele probleme de sistem, în timpul reinstalării va fi necesară cheia de produs Windows 10.

Licența se poate găsi pe windows 10 cu programe adiționale ceea ce nu aș recomanda (deoarece aceste programe fac schimb de informații dintre pc și producător în scopuri de îmbunătățire,ceea ce ar fi posibil să se creeze anumite breșe de securitate si să vă treziți că licența nu mai funcționează),sau mai sigur poți folosi metoda de astăzi care este mult mai simplă deoarece nu folosim niciun program adițional.

Cu un cod pe care o să îl plasați într-un document text după care salvați acest document sub extensia vbs (virtual basic script – Scriptul VB poate citi valoarea din registru și apoi îl poate traduce în formatul necesar pentru reinstalare),moment în care o să aveți progrămelul vostru ca să îi spunem așa cu care descoperiți printr-un click licența pc-ului,acest cod poate fi dezvoltat mai mult de atât însă pentru tutorialul de astăzi este suficient.

Așadar acest cod vă scutește de instalarea altor programe adiționale,și simplifică soluționarea descoperii licenței fără prea multe bătăi de cap.

COD

Option Explicit  
 
Dim objshell,path,DigitalID, Result  
Set objshell = CreateObject("WScript.Shell") 
'Set registry key path 
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\" 
'Registry key value 
DigitalID = objshell.RegRead(Path & "DigitalProductId") 
Dim ProductName,ProductID,ProductKey,ProductData 
'Get ProductName, ProductID, ProductKey 
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName") 
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID") 
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)  
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey 
'Show messbox if save to a file  
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then 
   Save ProductData  
End If 
 
 
 
'Convert binary to chars 
Function ConvertToKey(Key) 
    Const KeyOffset = 52 
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert 
    'Check if OS is Windows 8 
    isWin8 = (Key(66) \ 6) And 1 
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4) 
    i = 24 
    Maps = "BCDFGHJKMPQRTVWXY2346789" 
    Do 
           Current= 0 
        j = 14 
        Do 
           Current = Current* 256 
           Current = Key(j + KeyOffset) + Current 
           Key(j + KeyOffset) = (Current \ 24) 
           Current=Current Mod 24 
            j = j -1 
        Loop While j >= 0 
        i = i -1 
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput 
        Last = Current 
    Loop While i >= 0  
     
    If (isWin8 = 1) Then 
        keypart1 = Mid(KeyOutput, 2, Last) 
        insert = "N" 
        KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0) 
        If Last = 0 Then KeyOutput = insert & KeyOutput 
    End If     
     
 
    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5) 
    
     
End Function 
'Save data to a file 
Function Save(Data) 
    Dim fso, fName, txt,objshell,UserName 
    Set objshell = CreateObject("wscript.shell") 
    'Get current user name  
    UserName = objshell.ExpandEnvironmentStrings("%UserName%")  
    'Create a text file on desktop  
    fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt" 
    Set fso = CreateObject("Scripting.FileSystemObject") 
    Set txt = fso.CreateTextFile(fName) 
    txt.Writeline Data 
    txt.Close 
End Function

Copiați acest cod într-un document text după care îl salvați cu extensia vbs ,însă pentru mai multe detalii vă rog urmăriți tutorialul video de mai jos.

Tutorial Video

COMMENTS

WORDPRESS: 2
  • comment-avatar
    Okas 3 luni ago

    Mie imi arata cu totul alt key”serial” fata de cel pe care il detin eu.

    • comment-avatar

      Am facut update la cod acum poti salva si sub format text ,deasemenea am încercat licenta extrasa din pc-ul meu si funcționeaza ca activă ,mai incearca odata cu acest cod însa daca ai facut upgrade-ul gratuit la windows 10, licenta veche se pierde si se activeaza o alta licenta cu care vine win 10 .
      Acum mai nou daca ai windows-ul licentiat nu ai nevoie decat de MediaCreationTool cu aceasta unealta vei descarca automat windows-ul potrivit pentru pc ,nefiind necesar sa mai pui licenta inca odata deoarece MediaCreationTool va analiza pc-ul va sesiza ca ai un windows 10 licentiat iar apoi va descarca windows-ul functional cu tot cu licenta doar pentru pc-ul tau.